Библиотека Low-Power

После предыдущих публикаций я не могу не упомянуть о библиотеке Low-Power. Данная библиотека предназначена для управления режимами энергосбережения Ардуино. Чтобы перевести Ардуино в интересующий режим достаточно вызвать соответствующую функцию:

• idle;
• adcNoiseReduction;
• powerDown;
• powerSave;
• powerStandby;
• powerExtStandby;
• standby.

Каждая из этих функций имеет параметр для указания периода пребывания микроконтроллера в данном режиме (т.е. будет задействован WatchDog таймер для пробуждения) - от 15мс до 8с. Если периодическое пробуждение не требуется, то при вызове функции следует указать значение SLEEP_FOREVER. Остальные параметры функций предназначены для отключения периферии микроконтроллера, я не стану их перечислять и объяснять, вместо этого предлагаю заглянуть в файл LowPower.cpp, там все подробно расписано. Попробуйте найти, например, строку Name: powerDown - с нее начинается описание данной функции, приводятся ее параметры, их назначение и возможные значения.

С библиотекой идут несколько примеров для пробуждения Ардуино по сторожевому таймеру и от внешнего прерывания. Давайте рассмотрим пример powerDownWakeExternalInterrupt.ino, его листинг с моими комментариями приведен ниже.

// **** INCLUDES *****
#include "LowPower.h"

// Используем пин 2 для пробуждения
const int wakeUpPin = 2;

void wakeUp(){
  // Обработчик прерывания от пина 2
}

void setup(){
  // Настраиваем наш пин на ввод и задействуем подтягивающий резистор
  pinMode(wakeUpPin, INPUT_PULLUP);   
}

void loop(){
  // Разрешаем внешнее прерывание на пине 2 при низком уровне
  attachInterrupt(0, wakeUp, LOW);

  // Переводим Ардуино в режим power down с отключением модулей ADC и BOD
  // Остальные модули в этом режиме уже отключены
  LowPower.powerDown(SLEEP_FOREVER, ADC_OFF, BOD_OFF); 
  // При низком логическом уровне на пине 2 будет сгенерировано прерывание
  // и после вызова обработчика wakeUp() выполнение данной функции продолжится

  // Временно запретим прерывания, они пока не нужны
  detachInterrupt(0); 

  // А здесь должен быть код, который будет выполняться при пробуждении Ардуино
  // Это может быть опрос датчиков, обработка данных, передача или отображение 
  // информации и т.п.
}

Я лишь изменил режим работы пина 2 на INPUT_PULLUP, чтобы по умолчанию на нем всегда был высокий уровень и не требовался внешний подтягивающий резистор. Обработчик прерывания wakeUp не содержит кода, он здесь и не нужен, т.к. единственная задача внешнего прерывания - это разбудить микроконтроллер. При вызове функции powerDown выполняются те же действия, что и в моем скетче MinimizingPowerConsumption из предыдущей публикации. Конечно, здесь это все делается короче и проще. Единственное ограничение данной библиотеки - это тип используемого микроконтроллера.

На момент написания статьи библиотека Low-Power поддерживает следующие микроконтроллеры:

• ATMega168
• ATMega328P
• ATMega32U4
• ATMega2560
• ATMega256RFR2
• ATSAMD21G18A

Поэтому если вы работаете, например, с tiny85, то переводить ее в энергосберегающий режим придется вручную. А в целом библиотека весьма удачная, можете смело использовать ее для создания энергоэффективных устройств на Ардуино.