LiquidCrystal_I2C_Menu - библиотека для создания меню на ЖК дисплее и Ардуино. Новые возможности

В одной из прошлых публикаций я писал о своей библиотеке LiquidCrystal_I2C_Ext для создания меню на текстовом LCD дисплее и энкодере вращения. Библиотека получилась довольно интересная. Только название, как выяснилось впоследствии, уже используется. Поэтому я принял решение переименовать её в LiquidCrystal_I2C_Menu. Кроме нового имени в ней появились и новые возможности. А недавно я сделал версию библиотеки для управления с помощью кнопок - LiquidCrystal_I2C_Menu_Btns. Итого на ваш выбор представлены две библиотеки, о которых пойдет речь в сегодняшней статье.

Где качать

Библиотеки находятся на github по ссылкам:

https://github.com/VladimirTsibrov/LiquidCrystal_I2C_Menu - управление энкодером

https://github.com/VladimirTsibrov/LiquidCrystal_I2C_Menu_Btns - управление кнопками

Чтобы скачать интересующую библиотеку необходимо нажать на кнопку Code, затем Download ZIP:

Для установки библиотеки в среду Arduino распакуйте содержимое архива в папку Arduino_dir\libraries\ и удалите из названия "-master".

Как подключать

Библиотеки предназначены для работы с дисплеями LCD2004 и LCD1602 с I2C интерфейсом. Для управления потребуются либо энкодер вращения с кнопкой, например, KY-040, либо 3-4 кнопки. Схемы их подключения к Ардуино приведены ниже:

Схема подключения дисплея и энкодера к Ардуино для работы с LiquidCrystal_I2C_Menu

Схема подключения дисплея и кнопок к Ардуино для работы с LiquidCrystal_I2C_Menu_Btns

Вы можете выбрать для подключения любые другие пины Ардуино. Только не забудьте потом прописать их в скетче, чтобы библиотека знала, с какими выводами ей работать.

Для библиотеки LiquidCrystal_I2C_Menu_Btns достаточно трёх кнопок. Четвертая опциональная, используется для отмены действий и возврата из функций.

Как использовать

Обе библиотеки одинаковы в использовании, за исключением функций подключения и опроса элементов управления (attachEncoder / attachButtons и getEncoderState / getButtonsState). В остальном они взаимозаменяемы. Помимо унаследованных из LiquidCrystal_I2C функций в них реализованы следующие:

• printAt(x, y, text) – вывод текста на дисплей с указанной позиции.
• printf(format, …) – форматированный вывод текста. Лично мне очень не хватало этой функции. Если раньше приходилось делать несколько вызовов print, или выводить текст в промежуточный буфер функцией sprintf, то сейчас достаточно одного вызова printf.
• printfAt(x, y, format, …) – форматированный вывод с указанной позиции.
• attachEncoder(pinA, pinB, pinBtn) – сообщает библиотеке, к каким выводам Ардуино подключен энкодер. Только для LiquidCrystal_I2C_Menu.
• getEncoderState() – опрос состояния энкодера. Возвращает значение типа eEncoderState (перечисляемый тип, описан в библиотеке как {eNone, eLeft, eRight, eButton}). Только для LiquidCrystal_I2C_Menu.
• attachButtons(pinLeft, pinRight, pinEnter, [pinBack]) – сообщает библиотеке, к каким выводам Ардуино подключены кнопки. Только для LiquidCrystal_I2C_Menu_Btns.
• getButtonsState() – опрос состояния кнопок. Возвращает значение типа eButtonsState (перечисляемый тип, описан в библиотеке как {eNone, eLeft, eRight, eButton, eBack}). Только для LiquidCrystal_I2C_Menu_Btns.
• printMultiline(text) – вывод длинного текста с возможностью вертикальной прокрутки. Возврат из функции осуществляется при нажатии кнопки.
• inputVal(title, min, max, default, [step = 1], [*onChangeFunc = NULL]) – ввод числового значения. title – заголовок; параметры min и max задают диапазон, в котором может изменяться значение; default – начальное значение; step – величина приращения, по умолчанию равна 1; необязательный параметр onChangeFunc – указатель на функцию, которая должна вызываться при изменении значения.
• inputValAt(x, y, min, max, default, [step = 1], [*onChangeFunc = NULL]) – аналогична функции inputVal, но в отличие от нее не очищает дисплей при вызове и ввод значения осуществляется с указанной позиции.
• inputValBitwise(title, value, precision, [scale = 0], [signed = false]) – позволяет вводить числовые значения путем редактирования отдельных разрядов числа. Параметр title определяет заголовок; value – ссылка на переменную, в которую будет помещен результат ввода; precision – общее количество разрядов в числе; scale – количество разрядов после запятой, значение по умолчанию 0; signed – разрешает (при значении true) или запрещает (при значении false – по умолчанию) ввод отрицательных чисел. Функция возвращает true, если пользователь подтвердил ввод, false, если отказался.
• inputStrVal(title, buffer, length, available_symbols) – аналогично функции inputValBitwise предоставляет возможность поразрядного ввода, но кроме цифр могут быть введены и другие символы. Параметр title определяет заголовок; buffer – ссылка на символьный буфер, в который будет помещен результат ввода; length – количество вводимых символов; параметр available_symbols – это строка символов, доступных для ввода. Функция возвращает true, если пользователь подтвердил ввод, false, если отказался.
• selectVal(title, list_of_values, count, [show_selected = true], [selected_index = 0]) – позволяет выбрать значение из списка list и возвращает индекс выбранного элемента.  title – отображаемый на дисплее заголовок; list – список значений для выбора, представляет собой массив значений типа char*, String или int; count – количество элементов в массиве; show_selected - флаг отображения метки на выбранном элементе; selected_index – индекс выбранного по умолчанию элемента.
• showMenu(menu, menu_length, show_title) – отображает меню и возвращает ключ выбранного элемента. menu – массив элементов типа sMenuItem; menu_length – длина меню; show_title – признак необходимости отображения заголовка.
• getSelectedMenuItem() – возвращает ключ выбранного пункта меню для использования внутри обработчиков.
• attachIdleFunc(*IdleFunc) – позволяет привязать функцию, которая будет вызываться библиотекой при бездействии.

 Разберём несколько примеров их использования.

printAt, printf, printfAt

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

void setup() {
  char hello[] = "Hello, world!";
  String s = "String example";
  lcd.begin();
  lcd.printf("millis=%lu", millis());
  lcd.printAt(3, 1, hello);
  lcd.printAt(0, 2, s);
  lcd.printfAt(0, 3, "%s", s.c_str());
}

void loop() {

}

Результат работы функций printAt, printf, printfAt

Функция printAt поддерживает те же типы данных, что и print: вы можете выводить на дисплей целые и дробные числа, текстовые строки, будь то массив символов или переменная типа String. А при работе с функциями форматированного вывода printf и printfAt не забывайте, что они не поддерживают тип String и передавать им нужно указатель на строку в стиле Си. Для этого достаточно вызвать функцию c_str() класса String, в примере выше это показано.

attachEncoder, getEncoderState и attachButtons, getButtonsState

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

int x = 0;

void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
  lcd.printfAt(0, 0, "%d ", x);
}

void loop() {
  // Опрашиваем энкодер
  eEncoderState EncoderState = lcd.getEncoderState();
  switch (EncoderState) {
    case eLeft:   // При вращении влево уменьшаем значение переменной
      x--;
      break;
    case eRight:  // При вращении вправо увеличиваем значение переменной
      x++;
      break;
    case eButton: // При нажатии кнопки энкодера обнуляем значение переменной
      x = 0;
      break;
    case eNone:   // Энкодер не вращается, кнопка не нажата. Выходим из функции
      return;
  }
  lcd.printfAt(0, 0, "%d ", x); // Покажем новое значение x
}

В данном примере выполняется подключение энкодера функцией attachEncoder и опрос его состояния в цикле. При вращении энкодера изменяется значение переменной x, затем выводится на дисплей. Нажатие на кнопку приводит к обнулению переменной.

Аналогичный пример для библиотеки LiquidCrystal_I2C_Menu_Btns вы найдете в папке \examples\Buttons. Отличие состоит в использовании функций attachButtons и getButtonsState. Последняя возвращает значение типа eButtonsState, которое определено в библиотеке следующим образом:

enum eButtonsState {eNone, eLeft, eRight, eButton, eBack};

Это те же значения, что используются при работе с энкодером, плюс новое значение eBack для кнопки "Назад". Подключать эту кнопку необязательно, то есть функция attachButtons может быть вызвана с тремя параметрами:

lcd.attachButtons(pinLeft, pinRight, pinEnter);

printMultiline

#include <avr/pgmspace.h>
#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

// Объявим две строки в памяти программ. Так они не будут занимать оперативную память
const char text_1[] PROGMEM = "Using PROGMEM example";
const char text_2[] PROGMEM = "This text is stored in FLASH";

const char* const text[] PROGMEM = {text_1, text_2};

void setup() {
  lcd.begin();
    lcd.attachEncoder(pinDT, pinCLK, pinSW);
}

void loop() {
  char *buffer;
  // Вывод на экран длинной строки. Строка занимает оперативную память.
  lcd.printMultiline("Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua");
  
  // Вывод строки из памяти программ.
  buffer = (char*) malloc(30); // Буфер для временного хранения строки
  strcpy_P(buffer, (char*)pgm_read_word(&(text[0]))); // Копируем строку в буфер
  lcd.printMultiline(buffer); // Выводим содержимое буфера на экран
  strcpy_P(buffer, (char*)pgm_read_word(&(text[1]))); // Аналогично со второй строкой
  lcd.printMultiline(buffer);
  free(buffer); // Освобождаем буфер
  
  // Другой пример хранения строк в памяти программ - использование макроса F().
  lcd.printMultiline(F("Using F() macro example. Press button to continue."));
}

Результат работы функции printMultiline

Функция printMultiline позволяет выводить на дисплей длинные строки с возможностью прокрутки. Но, объявив несколько таких строк в своем скетче, при компиляции вы можете заметить, как быстро они "съедают" память данных. В Ардуино Уно для хранения данных доступно всего 2кб, тогда как для кода программы отведено 32кб. Поэтому при наличии в программе большого объема текстовых данных целесообразно хранить их в памяти программ (FLASH). Для этого используется ключевое слово PROGMEM. 

PROGMEM – это модификатор переменных, он сообщает компилятору, что указанная переменная должна быть размещена не в памяти данных, а в памяти программ. Работает этот модификатор только с типами данных, объявленными в файле pgmspace.h, частью которой он является. Чтобы впоследствии процессор мог что-то сделать с этими данными, они должны быть скопированы из FLASH в SRAM. Для этого в примере выше выделяется буфер, в который происходит считывание строк text[0] и text[1]. После того как данные выведены на дисплей буфер может быть освобожден.

Еще один вариант размещения строки в памяти программ – это использование макроса F() непосредственно в функции printMultiline. В примере это также показано.

inputVal, inputValAt

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
}

void loop() {
  // Для примера запросим длину массива
  uint8_t len = lcd.inputVal("Input array len", 5, 10, 8);
  uint8_t A[len];
  uint8_t t;
  
  // Затем элементы массива
  for (uint8_t i = 0; i < len; i++) {
    lcd.printfAt(0, 0, "Input A[%d]: ", i); // Приглашение для ввода
    A[i] = lcd.inputValAt(12, 0, 0, 9, 5);  // Ввод значения
  }
  
  // Отсортируем массив
  for (uint8_t i = 0; i < len - 1; i++) {
    for (uint8_t j = i + 1; j < len; j++) {
      if(A[i] > A[j]){
        t = A[i];
        A[i] = A[j];
        A[j] = t;
      }
    }
  }
  
  // И выведем на дисплей
  lcd.clear();
  lcd.print("Sorted array:");
  lcd.setCursor(0, 1);
  for (uint8_t i = 0; i < len; i++)
    lcd.printf("%d ", A[i]);
  
  // Ожидаем нажатия кнопки для продолжения
  while (lcd.getEncoderState() == eNone);
}

Использование функций printfAt и inputValAt для ввода значений

Для демонстрации использования функций inputVal и inputValAt в данном примере предлагается ввести длину массива, а затем элементы массива. Введенный массив сортируется и выводится на дисплей. Отличие этих двух функций состоит в том, что inputValAt при вызове не очищает дисплей и позволяет предварительно вывести на дисплей заголовок, используя printf. В скетче выше это используется для отображения индекса вводимого элемента массива.

В некоторых случаях необходимо знать значение переменной в процессе её редактирования, а не по завершении редактирования. Это позволило бы оперативно применять новое значение. Тогда, например, при изменении громкости мы сможем не только видеть её новое значение на дисплее, но и воспринимать изменение на слух. Для таких случаев в функциях inputVal и inputValAt предусмотрен параметр onChangeFunc. В нём передаётся указатель на функцию, которая должна вызываться при каждом изменении редактируемого параметра. Внутри такой функции можно применить новое значение параметра или даже визуализировать его ввод: отобразить шкалу как в примере ниже.

Шкала ввода для функций inputVal и inputValAt

В примерах к библиотеке есть скетч inputVal_onChange, поясняющий использование параметра onChangeFunc.

inputValBitwise

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

double val = 0;

void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
}

void loop() {
  // Ввод 5-значного числа со знаком, 2 цифры после запятой:
  if (lcd.inputValBitwise("Input value", val, 5, 2, true)) {
    lcd.print("You entered: ");
    lcd.print(val);
  }
  else
    lcd.print("Input canceled");
  while (lcd.getEncoderState() == eNone);
}

Пример использования функции inputValBitwise для поразрядного ввода чисел

Параметры, с которыми вызывается функция inputValBitwise в данном скетче, определяют ввод пятиразрядного числа со знаком, два младших разряда отведены для дробной части. При подтверждении ввода функция возвращает true и помещает введённое значение в переменную val.

Ещё несколько примеров ввода чисел функциями inputVal и inputValBitwise вы найдёте в скетче Input_double_and_long.

inputStrVal

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

char ip[] = "192.168.001.001"; // Массив символов с начальным значением/маской

void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
}

void loop() {
  if (lcd.inputStrVal("Input IP", ip, 15, "0123456789")){
    lcd.print("You entered:");
    lcd.printAt(0, 1, ip);
  }
  else
    lcd.print("Input canceled");
  while (lcd.getEncoderState() == eNone);
}

Пример использования функции inputStrVal для маскированного ввода

Здесь функция inputStrVal используется для ввода IP адреса. При вызове функции содержимое переданного буфера рассматривается как значение по умолчанию и выводится на дисплей. Последний параметр функции определяет разрешенные для ввода символы, в данном случае только цифры. Если буфер содержит символы, которые не могут быть введены, то их не удастся изменить. Таким способом можно реализовать маскированный ввод или, например, показать единицу измерения для вводимого значения.

selectVal

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

int index = 0;
  
void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
}

void loop() {
  String list[] = {"Europa+", "Record", "DFM", "Retro FM", "Energy"};
  index = lcd.selectVal("Select station", list, 5, true, index);
  lcd.printf("%s selected", list[index].c_str());
  while (lcd.getEncoderState() == eNone);
}

Пример работы функции selectVal

Функция selectVal используется для выбора значения из списка. Она работает с массивами значений типа char*, String или int и возвращает индекс выбранного элемента. Последние два параметра функции необязательны, это show_selected - определяет, должно ли визуально выделяться выбранное значение (по умолчанию true) и  preselected - задаёт индекс выбранного элемента (по умолчанию -1 - ничего не выбрано).

showMenu

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

// Объявим перечисление, используемое в качестве ключа пунктов меню
enum {mkBack, mkRoot, mkRun, mkOptions, mkMode, mkSpeed, mkLog, mkSelftest, mkHelp, mkFAQ, mkIndex, mkAbout};

// Описание меню
// структура пункта меню: {ParentKey, Key, Caption, [Handler]}
sMenuItem menu[] = {
  {mkBack, mkRoot, "Menu demo"},
    {mkRoot, mkRun, "Run"},
    {mkRoot, mkOptions, "Options"},
      {mkOptions, mkMode, "Mode"},
      {mkOptions, mkSpeed, "Speed"},
      {mkOptions, mkLog, "Print log"},
      {mkOptions, mkSelftest, "Selftest"},
      {mkOptions, mkBack, "Back"},
    {mkRoot, mkHelp, "Help"},
      {mkHelp, mkFAQ, "FAQ"},
      {mkHelp, mkIndex, "Index"},
      {mkHelp, mkAbout, "About"},
      {mkHelp, mkBack, "Back"},
    {mkRoot, mkBack, "Exit menu"}
};

uint8_t menuLen = sizeof(menu) / sizeof(sMenuItem);

void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
}

void loop() {
  // Показываем меню
  uint8_t selectedMenuItem = lcd.showMenu(menu, menuLen, 1);
  // И выполняем действия в соответствии с выбранным пунктом
  if (selectedMenuItem == mkRun)
    lcd.print("Run selected");
  else if (selectedMenuItem == mkMode)
    lcd.print("Mode selected");
  else if (selectedMenuItem == mkSpeed)
    lcd.print("Speed selected");
  else if (selectedMenuItem == mkLog)
    lcd.print("Print log selected");
  else if (selectedMenuItem == mkSelftest)
    lcd.print("Selftest selected");
  else if (selectedMenuItem == mkFAQ)
    lcd.print("FAQ selected");
  else if (selectedMenuItem == mkIndex)
    lcd.print("Index selected");
  else if (selectedMenuItem == mkAbout)
    lcd.print("About selected");
  else if (selectedMenuItem == mkBack)
    lcd.print("Exit selected");
  delay(2000);
}

Пример меню, построенного функцией showMenu

Функция showMenu берёт на себя отрисовку меню и навигацию по нему. Входными параметрами функции являются массив элементов типа sMenuItem (это и есть наше меню), длина массива и признак отображения заголовка в меню. В качестве заголовка используется название родительского пункта меню. Отключение отображения заголовка полезно при использовании дисплея 1602.

Итак, меню - это массив элементов sMenuItem. Данная структура определёна в библиотеке следующим образом:

struct sMenuItem {
  uint8_t parent;
  uint8_t key;
  char    *caption;
  void    (*handler)();
};

Параметры parent и key служат для задания иерархии, caption – указатель на название элемента меню, handler - указатель на функцию, которая будет вызываться при выборе данного пункта меню. Будем называть такие функции обработчиками.

В качестве parent и key могут быть использованы целочисленные значения, начиная с 1. Но гораздо удобнее определить для них символьные имена, то есть работать с перечислением. Обратите внимание на то, что первым в перечислении должно быть определено значение mkBack, ему соответствует значение 0. Данное значение является служебным и используется для пунктов меню, отвечающих за возврат на уровень выше.

При выборе пункта меню, не имеющего подменю и обработчика, функция возвращает соответствующее ему значение key. После этого остаётся проанализировать вернувшееся значение при помощи if или case и выполнить соответствующее выбранному элементу действие.

Если же для выбранного пункта меню задан обработчик, то он будет вызван, после чего управление вернётся в меню.

getSelectedMenuItem и использование обработчиков меню

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

int brightness = 50;
int _delay = 10;

// Обработчики пунктов меню SetBrightness и SetDelay
// Используются для ввода значений brightness и _delay
void SetBrightness() {
  brightness = lcd.inputVal("Input brightness(%)", 0, 100, brightness, 5);
}

void SetDelay() {
  _delay = lcd.inputVal("Input delay(ms)", 0, 20, _delay);
}

// Объявим перечисление, используемое в качестве ключа пунктов меню
enum {mkBack, mkRoot, mkOptions, mkSetBrightness, mkSetDelay};

// Описание меню
// структура пункта меню: {ParentKey, Key, Caption, [Handler]}
sMenuItem menu[] = {
  {mkBack, mkRoot, "Main menu", NULL},
  {mkRoot, mkOptions, "Options", NULL},
  {mkOptions, mkSetBrightness, "SetBrightness", SetBrightness},
  {mkOptions, mkSetDelay, "SetDelay", SetDelay},
  {mkOptions, mkBack, "Back", NULL},
  {mkRoot, mkBack, "Back", NULL}
};

uint8_t menuLen = sizeof(menu) / sizeof(sMenuItem);

void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
}

void loop() {
  uint8_t selectedMenuItem = lcd.showMenu(menu, menuLen, 1); // Вызываем меню
  /* Реакция на выбор пунктов меню SetBrightness и SetDelay реализована
   * в функциях-обработчиках.
   * При необходимости здесь может располагаться анализ значения selectedMenuItem 
   * для пунктов, не имеющих обработчиков:
     if (selectedMenuItem == ...) {...}
  */
}

В этом примере для двух пунктов меню заданы функции-обработчики SetBrightness и SetDelay. Они не имеют параметров и ничего не возвращают - это обязательное требование к обработчикам. Обработчики вызываются прямо из функции showMenu, то есть она не завершается и не возвращает ключ выбранного пункта меню. Внутри обработчиков можно как угодно работать с дисплеем, перерисовывать его и вызывать функции библиотеки, после завершения обработчика меню будет восстановлено.

Один обработчик можно привязать сразу к нескольким пунктам меню. В этом случае, чтобы понять, какой пункт был выбран, используется функция getSelectedMenuItem. Она возвращает ключ выбранного пункта. Далее ключ нужно проанализировать и выполнить соответствующий код.

attachIdleFunc

При вызове большинства функций библиотеки ожидается действие от пользователя: выбор пункта в меню, ввод значения и так далее. При этом мы по сути находимся в цикле и выполнение остальной части программы невозможно, пока мы не выйдем из этого цикла. Это логично. Но возможны случаи, когда такая логика работы не подходит. Например, если нам нужно опрашивать какие-либо датчики даже во время работы меню. В таких случаях поможет функция attachIdleFunc. Она позволяет указать функцию, которую будет вызывать библиотека снова и снова, пока мы находимся в меню, вводим или выбираем значения. А уже внутри этой самой функции можно сделать опрос датчиков или что угодно, что не будет долго выполняться, чтобы не мешать библиотеке опрашивать кнопки и энкодер.

Для демонстрации описанного функционала в приведённом ниже примере включается и выключается встроенный светодиод Ардуино, пока мы находимся внутри функций inputVal и printMultiline.

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

// Пины, к которым подключен энкодер
#define pinCLK 2
#define pinDT  3
#define pinSW  4

unsigned long tm = 0;
bool ledState = false;

// Данная функция будет вызываться из библиотеки при бездействии
void myIdleFunc() {
  if (millis() - tm >= 500) {
    // Включаем и выключаем встроенный светодиод на Ардуино
    tm = millis();
    ledState = !ledState;
    digitalWrite(LED_BUILTIN, ledState);
  }
}

void setup() {
  lcd.begin();
  lcd.attachEncoder(pinDT, pinCLK, pinSW);
  lcd.attachIdleFunc(myIdleFunc);
  pinMode(LED_BUILTIN, OUTPUT);
  lcd.print("Press the button");
}

int x = 0;

void loop() {
  myIdleFunc();
  if (lcd.getEncoderState() == eButton) {
    // Для проверки вызовем любую функцию библиотеки,
    // которая ожидает действий от пользователя:
    x = lcd.inputVal("Input some val", 0, 100, x);
    lcd.printMultiline("Some text here");
    lcd.clear();
    lcd.print("Press the button");
  }
}

Изначально myIdleFunc вызывается внутри функции loop, в результате светодиод мигает. При нажатии на кнопку энкодера происходит вызов функций библиотеки, выполнение loop приостанавливается. Тем не менее светодиод продолжает мигать, поскольку myIdleFunc вызывается библиотекой. И работе функций inputVal и printMultiline это не мешает.

Изменение названий пунктов меню

Ещё один приём, который я хочу показать, это изменение названий пунктов меню в ходе работы программы. Может пригодиться для отображения значений переменных в пунктах меню. В библиотеках есть примеры таких скетчей: Updating_menu_captions и Menu_for_setting_params.

Пример изменения названий пунктов меню

Поддержка дисплеев с кириллицей

Если ваш дисплей поддерживает кириллицу, то для корректного отображения русского текста необходимо включить её поддержку в самой библиотеке. Для этого в заголовочном файле (LiquidCrystal_I2C_Menu.h или LiquidCrystal_I2C_Menu_Btns.h) найдите и раскомментируйте строку:

#define CYRILLIC_DISPLAY

После этого сохраните внесённые изменения. Теперь русские буквы могут быть использованы в меню и других функциях библиотеки. Не забывайте, что для хранения одной русской буквы используется два байта, а не один. Поэтому для строки из N русских букв следует выделять N * 2 + 1 байт памяти.

Кроме того, при включении поддержки кириллицы вам станут доступны следующие функции:

uint8_t strlenUTF8(char *s)
void substrUTF8(char* source, char* dest, uint8_t fromPos, uint8_t count)

Функция strlenUTF8 возвращает длину строки s в символах (а не байтах, в отличие от функции strlen). Функция substrUTF8 копирует подстроку из строки source, начиная с символа fromPos, длиной count символов (опять же символов, а не байтов) в строку dest. Эти функции не являются методами классов LiquidCrystal_I2C_Menu / LiquidCrystal_I2C_Menu_Btns и вызываются "напрямую", без указания имени экземпляра класса, например:

#include <Wire.h>
#include <LiquidCrystal_I2C_Menu.h>
LiquidCrystal_I2C_Menu lcd(0x27, 20, 4);

void setup() {
  lcd.begin();
  char myText[] = "Привет, мир!";
  char mySubstr[21];
  lcd.print(strlenUTF8(myText)); // Напечатает "12"
  substrUTF8(myText, mySubstr, 8, 3);
  lcd.printAt(0, 1, mySubstr);   // Напечатает "мир"
}

void loop() {
  
}

Другие параметры

Кроме упомянутого выше CYRILLIC_DISPLAY заголовочные файлы библиотек содержат и другие параметры, которые могут быть изменены. Рассмотрим их.

#define SCROLL_LONG_CAPTIONS

- Данный параметр включает прокрутку длинных пунктов меню. Если такая возможность не нужна, просто закомментируйте данную строку. Это позволит немного уменьшить размер скомпилированного кода. Если же прокрутка нужна, то обратите внимание на временные интервалы данной функции:

#define SCROLL_DELAY        800  // Задержка прокрутки
#define DELAY_BEFORE_SCROLL 4000 // Задержка перед началом прокрутки
#define DELAY_AFTER_SCROLL  2000 // Задержка после вывода всей строки

- Они определяют скорость прокрутки и задержки перед её началом и в конце.

#define ENCODER_POOL_DELAY 5

- Интервал опроса энкодера (только для библиотеки LiquidCrystal_I2C_Menu). Я всегда использую 5мс. Может быть кому-то понадобится установить другое значение

#define BUTTONS_POOL_DELAY 50
#define BUTTONS_HOLD_BEFORE_REPEAT 1000

- Определяют интервал опроса кнопок и задержку при удержании кнопки нажатой (только для библиотеки LiquidCrystal_I2C_Menu_Btns). По истечении интервала BUTTONS_HOLD_BEFORE_REPEAT нажатая кнопка будет читаться как повторно нажатая каждые BUTTONS_POOL_DELAY мс до тех пор, пока она не будет отпущена.

Вместо заключения

При создании данных библиотек была проделана большая работа. Поэтому, надеюсь, вы оцените результат. Если возникнут вопросы по их использованию - пишите в комментариях, постараюсь на них ответить.