Работа с энкодером вращения с использованием прерываний

Теперь, когда мы научились избавляться от дребезга контактов (смотрите предыдущую статью), можно попробовать другой способ работы с энкодером: с использованием прерываний. Я буду экспериментировать все с тем же модулем KY-040, Arduino Uno и инвертирующим триггером Шмитта (SN74HC14N).

Для начала пара слов о прерываниях в Ардуино. Данная тема подробно изложена здесь и здесь. Сейчас же я ограничусь определением и небольшим описанием внешних прерываний Ардуино.

Прерывание - это сигнал от аппаратного обеспечения, сообщающий о наступлении некоторого приоритетного события, требующего немедленного внимания. В ответ на запрос прерывания микроконтроллер приостанавливает выполнение текущего кода и вызывает специальную функцию - обработчик прерывания (Interrupt Service Routine, ISR). Данная функция реагирует на событие, выполняя определенные действия, после чего возвращает управление в прерванный код.

Для работы с энкодером мы будем использовать внешние прерывания Ардуино. Внешними они называются потому, что их инициирует внешнее по отношению к микроконтроллеру устройство. Плата Arduino Uno (а также большинство других плат из семейства Ардуино), к которой я собираюсь подключать энкодер, может обрабатывать до двух внешних прерываний на цифровых выводах 2 и 3. Для этого необходимо задать функции обработки прерываний при помощи функции attachinterrupt(interrupt, function, mode). Параметры данной функции:

• interrupt - номер прерывания. Может быть указан явно (0 для цифрового вывода 2 и 1 для вывода 3 в случае использования Arduno Uno), но лучше воспользоваться функцией digitalPinToInterrupt(pin), которая по номеру вывода вернет номер привязанного к нему внешнего прерывания;
• function -  функция обработки прерывания - функция, которая будет вызываться каждый раз при возникновении прерывания. Должна быть без параметров и не возвращать никаких значений;
• mode - задает режим обработки прерывания. Может принимать одно из следующих значений:
• LOW - вызывает прерывание, когда на входе сигнал низкого уровня;
• CHANGE - вызывает прерывание при изменении уровня сигнала на входе;
• RISING - прерывание вызывается при изменении сигнала от низкого уровня к высокому;
• FALLING - прерывание вызывается при изменении сигнала от высокого уровня к низкому.

Для работы с прерываниями подключим модуль энкодера KY-040 к Ардуино по нижеприведенной схеме.

Все 3 вывода энкодера заводим на микросхему SN74HC14N для подавления дребезга контактов. Необходимо также учесть, что в модуле нет подтягивающего резистора для сигнала SW, поэтому он добавлен в схему.

Если раньше для того чтобы поймать момент изменения сигнала энкодера приходилось постоянно опрашивать цифровой вход и сравнивать его значение с предыдущим, то сейчас достаточно назначить обработчик прерывания функцией attachinterrupt. Так как в нашем распоряжении только 2 внешних прерывания, то одно из них будем использовать для отслеживания изменения сигнала CLK, второе для кнопки. Загрузите нижеприведенный код в Ардуино и проверьте его работу в мониторе порта: при вращении энкодера значение счетчика будет изменяться и выводиться в Serial, а при нажатии на кнопку счетчик сбрасывается.

#define pin_CLK 2 // Энкодер пин A
#define pin_DT  4 // Энкодер пин B
#define pin_Btn 3 // Кнопка

volatile long Position = 0;
long oldPosition = 0;

void EncoderRotate() {
  if (digitalRead(pin_CLK) == digitalRead(pin_DT)) {
    Position++;
  } else {
    Position--;
  }
}

void EncoderClick() {
  Position = 0;
}

void setup() {
  pinMode(pin_CLK, INPUT);
  pinMode(pin_DT, INPUT);
  pinMode(pin_Btn, INPUT);
  attachInterrupt(digitalPinToInterrupt(pin_CLK), EncoderRotate, RISING);
  attachInterrupt(digitalPinToInterrupt(pin_Btn), EncoderClick, RISING);
  Serial.begin (9600);
}

void loop() {
  if (oldPosition != Position)
  {
    Serial.println(Position);
    oldPosition = Position;
  }
}

При изменении сигнала CLK от низкого уровня к высокому вызывается функция EncoderRotate, которая проверяет сигнал DT и изменяет значение счетчика. Если в функции attachInterrupt установить режим обработки прерывания CHANGE, то функция EncoderRotate будет вызываться как по заднему фронту CLK, так и по переднему. Таким образом можно увеличить разрешение энкодера в 2 раза. А если мы задействуем внешнее прерывание и для сигнала DT (вместо кнопки) и напишем для него аналогичный обработчик, то 4 фронта дадут нам 4х кратное увеличение разрешения энкодера. Пример такой программы, а также другую полезную информацию по энкодерам вращения можно найти по ссылке https://playground.arduino.cc/Main/RotaryEncoders. Там же представлены несколько библиотек, одну из которых я предлагаю рассмотреть - это библиотека Encoder.

Библиотека для работы с энкодерами вращения Encoder (домашняя страница проекта: https://www.pjrc.com/teensy/td_libs_Encoder.html) использует очень эффективные обработчики прерываний, написанные на ассемблере и предусматривает три варианта подключения энкодера к Ардуино, определяющих эффективность работы:

• Наилучшая эффективность, достигается при подключении обоих сигналов энкодера к выводам, поддерживающим прерывания;
• Средняя эффективность, при подключении одного сигнала энкодера к поддерживающему внешнее прерывание выводу. Второй сигнал подключается к любому цифровому входу;
• Низкая эффективность будет получена при подключении энкодера к выводам Ардуино, не поддерживающим прерывания. При этом для отслеживания изменения сигналов используется метод, который мы рассматривали ранее при опросе энкодера в цикле программы.

Давайте установим данную библиотеку и, не изменяя схему подключения энкодера, загрузим в Ардуино следующий код.

#include "Encoder.h"

#define pin_CLK 2 // Энкодер пин A
#define pin_DT  4 // Энкодер пин B
#define pin_Btn 3 // Кнопка

long oldPosition = 0;
Encoder myEnc(pin_CLK, pin_DT);

void EncoderClick() {
  myEnc.write(0); // При нажатии кнопки сбрасываем позицию
}

void setup() {
  pinMode(pin_Btn, INPUT);
  // Назначаем обработчик прерывания для кнопки
  attachInterrupt(digitalPinToInterrupt(pin_Btn), EncoderClick, RISING);
  Serial.begin (9600);
}

void loop() {
  long newPosition = myEnc.read() >> 2;
  if (newPosition != oldPosition) {
    oldPosition = newPosition;
    Serial.println(newPosition);
  }
}

Проверьте результат в мониторе порта, он должен быть такой же, как и для предыдущего примера. Выше я описывал способ увеличения разрешения энкодера, он как раз используется в данной библиотеке. Поэтому считанное значение я делю в программе на 4 (сдвигаю вправо на 2 разряда). В остальном, полагаю, приведенный пример не должен вызывать вопросов.

Вот так просто можно задействовать прерывания для работы с энкодером и избавиться от необходимости опрашивать его в основном цикле. Чуть позже я поделюсь опытом создания пользовательского меню на Ардуино с использованием энкодера вращения.